1 'Is a M100/T102 LCD pixel ON or OFF?
2 'POINT.100 subrutine - RHPigford
3 CLS:PRINTCHR$(27)+"V":LINE (0,0)-(119,7),1,BF:LINE(125,0)-(239,0),1
4 INPUT"What x value (0-239)";X:PRINT@68,"X = "X
5 INPUT"What y value (0-63) ";Y:PRINT@108,"Y = "Y
6 GOSUB 100
7 PRINT@120,"P = "P;:IFP=-1THENPRINT" TRUE";: ELSE PRINT" FALSE";
8 STOP
100 'POINT.100 to test pixels on/off
110 'by R. H. Pigford  6-8-2003
120 'Uses cursor flash (on-off) to
130 'load himem w/ 6 bytes duplicate of
140 'the 6 LCD character bytes
150 'Input = x (0-239) and y (0-63)
160 'of LCD pixel to be tested for on
170 'C=curs col no:   R=curs row no
180 'BX=number of byte (0-5) under curs
190 'BT=number of bit in that byte
200 'to be tested (0 at top down to 7 
210 'at bottom).
220 'Need to complement B to invert vid
230 'Output P = True (-1) = it's ON or 
240 'P = False (0) = it'a OFF
250 E$=CHR$(27)
260 'pick which byte of the 6 bytes
270 'across cursor bytes: BX = 0  to 5
280 C=INT(X/6):BX%=INT(X-C*6)
290 'picks the target bit of that byte
300 R=INT(Y/8):BT%=INT(Y-R*8)
310 'flash the cursor on the target pix
320 PRINT E$"P"; 'cursor on
330 'flash cursor using PRINT@,Pos
340 PRINT@(40*R+C),"";'curs locn
350 'get the 6 bytes from himem area
360 B%=NOT(PEEK(65516+BX%))
370 'disable curs flash
380 CALL 30300 
390 'curs on,reenable flash
400 PRINT E$"Q"
410 'test target bit of target byte
420 T%=2^BT%:D%= B% AND T%
430 IFD%<>0 THEN P=-1:RETURN:ELSE P=0:RETURN